ＣＡＳＬ入門[11]

(since 1998/11)(更新　2004/02/26)

ＴＮＯ_２:ＣＡＳＬ入門[11]

情報系/IT系の広告を掲載しています。(広告一覧)

<a href="http://www.accesstrade.net/at/c.html?rk=010004w80000x6" target="_blank"><img src="http://www.accesstrade.net/at/r.html?rk=010004w80000x6" alt="資格・教育　ヒューマンアカデミー" border="0"></a>

本ページは、「Ｒｏｏｋ」仕様に対応済みです。

　「ＪＵＭＰ」命令で、同じ命令を繰り返し実行することが出来ました。しかし、先ほどのプログラムではいつまでたっても終わりません。
　繰り返しのことを「ループ」といい、いつまでたっても終わらないループを特に「無限ループ」と呼びます。ループをある所まで繰り返した後で終わらせるには、そのある所まで繰り返したことをプログラムで見つけ出す必要があります。

　次のプログラムは、２つの数を入力して、その積を表示します。

ＳＡＭＰＬＥ	ＳＴＡＲＴ
	ＲＥＡＤ	０
	ＳＴ	ＧＲ０，ＶＡＬ１
	ＲＥＡＤ	０
	ＳＴ	ＧＲ０，ＶＡＬ２
	ＬＡＤ	ＧＲ０，０	；ＳＵＭ＝０
	ＬＡＤ	ＧＲ１，０	；ＣＯＵＮＴ＝０
ＬＯＯＰ
	ＡＤＤＡ	ＧＲ０，ＶＡＬ１	；ＳＵＭ＋ＶＡＬ１
	ＬＡＤ	ＧＲ１，１，ＧＲ１	；ＣＯＵＮＴ＋１
	ＣＰＡ	ＧＲ１，ＶＡＬ２
	ＪＮＺ	ＬＯＯＰ	；IF COUNT≠VAL2
	ＷＲＩＴＥ	０
	ＥＸＩＴ
ＶＡＬ１	ＤＳ	１
ＶＡＬ２	ＤＳ	１
	ＥＮＤ

　「ＬＡＤ　ＧＲ１，０」は、「ＬＤ　ＧＲ１，ＧＲ０」としても同じ結果が得られます。一般に「ＬＤ」を使った方がオブジェクト・プログラムが短く、動作も速くなります。しかしここでは、「０」を明示するために「ＬＡＤ」を使いました。
　次の結果は、「５」と「７」を入力した場合の実行例です。
(chapter11-page2)

Input : GR0 = 5(0005)
Input : GR0 = 7(0007)
GR0=35(0023)
プログラムは、PR[001C;SAMPLE+28]が指定したEXIT命令で終了しました。

　新しい命令は「ＣＰＡ」と「ＪＮＺ」です。「ＣＰＡ」命令は、レジスタの内容と実効アドレスの指し示すアドレスの内容との比較を行います。「ＪＮＺ」命令は、直前の比較の結果が「等しくない」時に、「ＪＵＭＰ」命令と同様に実効アドレスをプログラム・レジスタに入れます。
　上のプログラムでは、ＧＲ１とＶＡＬ２の内容が等しくない間、ループの部分を繰り返し実行することになります。そして、等しくなったら、そのまま次の「ＷＲＩＴＥ」命令から実行を続けます。

　「ＣＰＡ」命令の様な数値の比較をする命令を 比較命令と言います。比較の結果はフラグ・レジスタという特殊なレジスタに入れられます。フラグ・レジスタは、ＦＲと表記されることもあり、Ｒｏｏｋのレジスタ表示欄にも表示されています。フラグ・レジスタは、比較命令で指定したレジスタから実効アドレスの内容を引いた場合の、その値が正・負・０のどれであるかを示します。（それぞれ、「＞」「＜」「＝」と対応します。）尚、実際には引き算は行われないので、汎用レジスタの内容は変化しません。
　比較命令には「ＣＰＡ」の他「ＣＰＬ」命令があります。「ＣＰＡ」命令が算術値（２の補数表現）での比較であるのに対し、「ＣＰＬ」命令は論理値（１６ビット非負整数）として比較します。
(chapter11-page3)

　指定レジスタ＝（ＦＦＦＦ）₁₆
　実効アドレスの内容＝（００００）₁₆
　ＣＰＡの結果＝（－１）－０＝－１＝負
　ＣＰＬの結果＝６５５３５－０＝６５５３５＝正

　指定レジスタ＝（００００）₁₆
　実効アドレスの内容＝（ＦＦＦＦ）₁₆
　ＣＰＡの結果＝０－（－１）＝１＝正
　ＣＰＬの結果＝０－６５５３５＝－６５５３５＝負

　プログラム・レジスタの内容を変える動作は、分岐（またはジャンプ）と言います。また、「ＪＵＭＰ」命令や「ＪＮＺ」命令の様な分岐動作をする命令を、分岐命令（またはジャンプ命令）と言い、他に「ＪＭＩ」命令などがあります。

フラグ・レジスタの内容と分岐動作の一覧
分岐命令	フラグ・レジスタの内容				動作
分岐命令	負	０	正	オーバ・フロー	動作
ＪＭＩ	○	×	×	－	負の時だけ、分岐
ＪＺＥ	×	○	×	－	０の時だけ、分岐
（ＪＭＺ）	○	○	×	－	負、０の時、分岐
ＪＰＬ	×	×	○	－	正の時だけ、分岐
ＪＮＺ	○	×	○	－	負、正の時、分岐
（ＪＰＺ）	×	○	○	－	０、正の時、分岐
ＪＵＭＰ	○	○	○	－	常に、分岐
ＪＯＶ	－	－	－	○	オーバ・フローの時だけ、分岐
「×」は、分岐動作をしません。「○」は、分岐動作をします。「－」は、分岐動作に影響しません。ＣＡＳＬIIには、ＪＭＺ命令とＪＰＺ命令は存在しません。他の分岐命令の組合せで、同じ動作をさせます。

　ＪＯＶ命令の動作の項にある「オーバ・フロー」については、次の章で説明します。
　尚、旧ＣＡＳＬでは、ＪＰＬ命令とＪＯＶ命令が無く、ＪＰＺ命令が存在していました。

(chapter11-page4)

１１-２．フラグ・レジスタの変化

　実は、フラグ・レジスタは比較命令以外でも変化します。例えば、「ＳＵＢＡ」命令の引き算の結果でも、フラグ・レジスタの内容が変わります。

フラグ・レジスタの内容が変化する命令
命令群	命令
比較命令	ＣＰＡ，ＣＰＬ
算術演算命令	ＡＤＤＡ，ＳＵＢＡ
論理演算命令	ＡＤＤＬ，ＳＵＢＬ
論理演算命令	ＡＮＤ，ＯＲ，ＸＯＲ
シフト命令	ＳＬＡ，ＳＲＡ，ＳＬＬ，ＳＲＬ
ロード命令	ＬＤ

　尚、旧ＣＡＳＬでは、ロード命令(ＬＤ)ではなく、ロード・アドレス命令(ＬＥＡ;現ＬＡＤに相当)でフラグが変化していました。
　フラグ・レジスタを変化させる命令の内、「ＣＰＡ」「ＣＰＬ」は汎用レジスタは変化せず比較のみです。その他の命令では、変化した汎用レジスタの値の２の補数表現での正・負・０と、演算による「オーバ・フロー」の有無が、フラグ・レジスタに入ります。尚、「オーバ・フロー」が設定されている時には、Ｒｏｏｋのレジスタ表示欄には「(OV)」と表示されます。
　「オーバ・フロー」とは、演算結果が有効な値の範囲を越えている、つまり演算結果が正しくないという意味です。その範囲は、算術演算では－３２７６８～３２７６７、論理演算では０～６５５３５の範囲です。ただし、「ＬＤ」、「ＡＮＤ」、「ＯＲ」、「ＸＯＲ」と比較命令では、汎用レジスタには常に有効な値が設定されるので、オーバ・フローは発生しません。又、シフト命令では、シフト動作の最後に追い出されたビットが１である時のみ、オーバ・フローが発生したと見なされます。
　「オーバ・フロー」は、汎用レジスタの１６ビットに入りきらず、追い出された１７番目のビットと見なすことも出来ます。ＣＡＳＬII以外のシステムでは、次の処理に持ち越されるビットということから、「キャリー(桁上がり)」と呼ばれることもあります。

　先ほどのプログラムを、書き換えてみましょう。

ＳＡＭＰＬＥ	ＳＴＡＲＴ
	ＲＥＡＤ	０	；ＳＵＭ
	ＳＴ	ＧＲ０，ＶＡＬ	；＝ＶＡＬ
	ＲＥＡＤ	１	；ＣＯＵＮＴ
ＬＯＯＰ
	ＳＵＢＡ	ＧＲ１，ＯＮＥ	；ＣＯＵＮＴ－１
	ＪＺＥ	ＬＥＮＤ	；IF COUNT＝0
	ＡＤＤＡ	ＧＲ０，ＶＡＬ	；ＳＵＭ＋ＶＡＬ
	ＪＵＭＰ	ＬＯＯＰ	；ＬＯＯＰ
ＬＥＮＤ
	ＷＲＩＴＥ	０
	ＥＸＩＴ
ＶＡＬ	ＤＳ	１
ＯＮＥ	ＤＣ	１
	ＥＮＤ

(chapter11-page5)
　「ＳＵＢＡ」命令で繰り返し数（ＧＲ１）を１づつ減らしています。ＧＲ１が減って行って０になると、フラグ・レジスタも０を表す様に成ります。そして、次の「ＪＺＥ」命令で、ループの部分の後ろへ分岐することになります。

	ＳＵＢＡ	ＧＲ１，ＯＮＥ	；ＣＯＵＮＴ－１
	ＪＺＥ	ＬＥＮＤ	；ＩＦＣＯＵＮＴ＝０

ＯＮＥ	ＤＣ	１

　ループ部分全体では、ＧＲ１が０になるまでＧＲ１を１づつ減らしながら繰り返す、ということになります。更に言い替えると、（ＧＲ１）回繰り返すということです。（厳密には、「ＡＤＤＡ」命令の部分は、（ＧＲ１－１）回の繰り返しになります。）
　途中の「ＡＤＤＡ」命令でもフラグ・レジスタは変化しますが、「ＪＺＥ」命令を実行する時点ではその変化は無効になっていることに注意して下さい。

　さて、このソース・プログラムは後ほど利用することになりますから、「２-３章」に示す方法によって、ファイルとして保存しておいて下さい。

質問・ご意見等、お待ちしております。

小野智章(小野情報設計)　
Mail to Mail連絡先

ＴＮＯ２:ＣＡＳＬ入門[11]

ＴＮＯ_２:ＣＡＳＬ入門[11]